/* A:matrix, V:variables, W:weight, FILENAME:file name */

def gettotaldegree(A,V0,W0){

	dp_ord(0)$

	N0=length(V0)$
	N=size(A)[0]$

	PROD=1$
	for(I=0;I<N0;I++){
		PROD=PROD*2$
	}

	VA=newmat(N0,PROD/2)$
	VB=newvect(N0)$

	RET=[]$
	ROW=newvect(N)$
	COLM=newvect(N)$

	for(K=0;K<PROD;K++){	
	
		for(I=0;I<N;I++){
			ROW[I]=0$
			COLM[I]=0$
		}

		Q=K$
		TV=[]$
		TW=[]$
		J=0$
		while(Q!=0){
			if(irem(Q,2)==1){
				VA[J][VB[J]]=K$
				VB[J]++$
				TV=cons(V0[J],TV)$
				TW=cons(W0[J],TW)$
			}
			Q=idiv(Q,2)$
			J++$
		}

		dp_set_weight(TW)$
		for(I=0;I<N;I++){

			for(J=0;J<N;J++){
			
				DEG=dp_td(dp_ptod(A[I][J],TV))$

				if(DEG>ROW[I])
					ROW[I]=DEG$

				if(DEG>COLM[J])
					COLM[J]=DEG$
		
			}
		
		}

		ROW0=0$
		COLM0=0$

		for(I=0;I<N;I++){
			ROW0+=ROW[I]$
			COLM0+=COLM[I]$
		}

		if(ROW0<COLM0)
			TMP=ROW0$
		else
			TMP=COLM0$

		RET=cons(TMP,RET)$

	}

	RET=reverse(RET)$
	return(RET)$
}

def max_degree(N,A,V){

        if(length(V)==0){
                return(-1)$
        }

        MAXDEG=0$

        for(I=0;I<N;I++){
                for(J=0;J<N;J++){
                        S=A[I][J]$
                        for(K=0;K<length(V);K++){
                                T=deg(S,V[K])$
                                if(MAXDEG<T){
                                        MAXDEG=T$
                                }
                        }
                }
        }

        return(MAXDEG)$
}

def asir2bin_det_simple(A,V,WEIGHT,FILENAME){

	dp_ord(0)$

	N0=length(V)$
	N=size(A)[0]$

        MAXDEG=max_degree(N,A,V)$

        TD=[]$
        for(I=0;I<length(WEIGHT);I++){
                W0=WEIGHT[I]$
                if(W0==0){
                        W0=[]$
                        for(J=0;J<N0;J++){
                                W0=cons(1,W0)$
                        }
                }
                TD=cons(gettotaldegree(A,V,W0),TD)$
        }
        TD=reverse(TD)$

	shell("rm -rf "+FILENAME)$
	output(FILENAME)$
	print("P",2)$
	print(0)$
	print("N",2)$
	print(N0)$
        print("X",2)$
        print(MAXDEG)$
  	print("V",2)$
	print(V)$
        for(I=0;I<length(WEIGHT);I++){
                print("W",2)$
                print(WEIGHT[I])$
        }
        for(I=0;I<length(TD);I++){
                print("T",2)$
                print(TD[I])$
        }
  	print("M",2)$
	print(N)$

	Z=0$
	Y=0$
	for(I=0;I<N;I++){
		for(J=0;J<N;J++){

			if((T=nmono(A[I][J]))>Y)
				Y=T$		

			if(A[I][J]!=0)
				Z++$

		}
	}

  	print("Z",2)$
	print(Z)$

  	print("Y",2)$
	print(Y)$

	for(I=0;I<N;I++){
		for(J=0;J<N;J++){

			if(A[I][J]==0){
				continue$
			}

			print("A",2)$
			print(I,2)$
			print(",",2)$
			print(J,2)$
			print(",",2)$
			print(nmono(A[I][J]),2)$
			print(",",2)$
			print(dp_ptod(A[I][J],V))$
		}
	}
	output()$
}

end$